!!!! fichier des questions de l'exercice 2 (X qualitative ; Y srie chrologique)
!!!! lu par var.init
!!!! MODE 2
!!!!!if $mode=2


ind=!randint 1,6
pop= !item $ind of placement boursier, fruits exotiques, sportifs, joueurs sur internet,foyers fiscaux, retraits
nompop= !item $ind of placement, fruit, sportif, joueur,foyer, retrait
nomX = !item $ind of  rendement annuel, prix au kg, temps  d'entranement,temps de jeu,revenu imposable,budget vacances
nomSX = !item $ind of  rendements annuels , prix , temps d'entranement,temps de jeu,revenus imposables,budgets vacances
unitX = !item $ind of euros,centimes,minutes,heures,euros,euros,euros
scaleX= !item $ind of 250, 500, 120, 15, 5000,2000
nomY = !item $ind of anne,semaine,semaine,jour,anne,anne
deY=!item $ind of de l',de la,de la,du,de l',de l'
leY=!item $ind of l',la,la,le,l',l'
!!!scaleY= !randitem   1, 2, 5
scaleY=1

!!!! create list of X resp. Y values of size nX (resp nY)

!if $niv=1
nX=2
nY=!randint 5,8
!else
nX=3
nY=!randint 8,12
!endif

nbsteps=3

X=A,B,C
min=1
Y=
!for i = 1 to $nY
     new= $[$min + ($i-1)*$(scaleY)] 
      Y=!append item $new to $Y
!next i

!!!! CREATE DATA (values) + TABLE (data X in row / time  Y in column )

!for x in $X
min=!randint 1,4
max=!randint 1,4
min=$[$scaleX*(1-$min/10)]
max=$[$scaleX*(1+$max/10)]
!for i= 1 to $nX
     row =
    moy = 0
    !for j= 1 to $nY
         new=!randint $min, $max
         row=!append item $new to $row
         moy = $[$moy + $new]
    !next j
     moy=$[$moy/$nY]
     moy=!exec pari 0.1*round(10*$moy)
     row= !append item $moy to $row
!!!!     moyennes= !append item $moy to $moyennes
     data= !append line $row to $data
!next i
data= !nonempty line $data



!!! TABLE (afficher tableau contenant data)

table=<table border=solid cellpadding="5" bgcolor=#FFFF66>
tr=!append word <tr><td align="center"><font color="red">rang $deY $nomY</font></td> to $tr
!for j= 1 to $nY
     el = !item $j of $Y
     tr=!append word <td align="center"><font color="red">$el</font></td> to $tr
!next j
tr = !append word <td >Moyenne</td></tr> to $tr
!!! table html  construite ligne aprs ligne 
table=!append word  $tr to $table
!for i = 1 to $nX
     tr=
     x1 = !item $i of $X
    first=<tr><td align="center"><font color="blue">$nompop $(x1)</font></td>     
     line = !line $i of $data 
     tr=!append word   $first to $tr
     !for j= 1 to $[$nY+1]
          el = !item $j of $line
          tr = !append word <td>$el</td> to $tr
     !next j 
     tr = !append word </tr> to $tr
     table = !append word $tr to $table
!next i
table = !append word </table> to $table


!!! les Questions (mode-dependent)

questions=
!!! step=1
quest= On s'intresse au $nompop A et on cherche  estimer son $nomX pour $leY $(nomY) de rang $[$nY+1]. <br/>
quest = !append word <b>a)</b> Calculer le pourcentage d'volution de son $nomX entre les deux dernires $(nomY)s. Donner la valeur arrondie  0.01%.<br/> to $quest
quest = !append word <b>b)</b> Si l'volution se poursuit selon le pourcentage obtenu en a), quel sera son $nomX  $leY  $(nomY) de rang $[$nY+1]? <br/> to $quest
questions=!append line $quest to $questions
!!! step=2
quest= On s'intresse  au $nompop B et on cherche  estimer  son $nomX pour la priode suivante. <br/> <br/>
quest = !append word  <b>a)</b> Calculer la moyenne des pourcentages d'volution successifs, $nomY aprs $nomY. Donner la valeur arrondie  0.01%.<br/> to $quest
quest = !append word <b>b)</b>  Si l'volution se poursuit selon le pourcentage obtenu en a), quel sera son $nomX  $leY $nomY de rang $[$nY+1]  ? to $quest
questions=!append line $quest to $questions
!!! step=3
quest= On compare maintenant les $(nomSX) moyens des deux $pop. Complter les champs de rponse, pour que l'affirmation ci-dessous soit vraie : <br/>
questions=!append line $quest to $questions
!!! choix vD,vA pour calcul question 3
ref=A,B 
ref=!append line B,A to $ref
quest=!randline  $ref
questions=!append line $quest to $questions


!!! les Rponses, dans l'ordre des questions

!!! reponses aux  questions 1 et 2
reponses=
!for s in 1,2
   serie=!line $s of $data
   !if $s=1
        vd=!item $[$nY-1] of $serie
        va=!item $[$nY] of $serie
        t=$[100*($va/$vd-1)]
!!! round bug avec 0
        !ifval $t!=0
             t=!exec pari 0.01*round(100*$t)
        !endif
   !else
        tot=0
        !for i = 1 to $[$nY-1]
              vd=!item $i of $serie
              va=!item $[$i+1] of $serie
              t=100*($va/$vd-1)
              tot = $[$tot +$t]
         !next i
         t = $[$tot/($nY-1)]
         !ifval $t!=0
              t=!exec pari 0.01*round(100*$t)
         !endif
   !endif
    est=!exec pari 0.1*round(10*$va*(1+$t/100))
    !ifval $t=0
         reponses = !append line 0,$t,$est,$vd,$va to $reponses
    !else
         !ifval $t>0
            reponses = !append line +,$t,$est,$vd,$va to $reponses
         !else
             t=!char 2 to -1 of $t
             reponses = !append line -,$t,$est,$vd,$va to $reponses
         !endif
     !endif
!next s
!!! rponses  la question 3
serie=!column $[$nY+1] of $data
!!! la premire lettre fixe la valeur de dpart pour le calcul de %
!if $quest=A,B
vd=!item 1 of $serie
va=!item 2 of $serie
!else
vd=!item 2 of $serie
va=!item 1 of $serie
!endif
t=$[100*($va/$vd-1)]
!ifval $t!=0
     t=!exec pari 0.01*round(100*$t)
!endif
!!!!! cas o t=0 , pas vraiment de sup/ inf !!??
!ifval $t>=0
          reponses = !append line sup,$t,$quest to $reponses
     !else
           t=!char 2 to -1 of $t
           reponses = !append line inf,$t,$quest  to $reponses
!endif

!!!!!endif
