!set n=$counter
!if $level=0
    R=$counter
!else
    R=$level
!endif  
var1=1
image=0
mathview=0
!if $rounding<100
    rounding=10000
    !readproc $remarkdir/rounding.$taal
!endif 
XSIZE=650
cols=20
rows=1
questiontype=0
formula$n=$empty
checkfile=exos/checkfile1.proc
exotext=$empty
#!record 15 of lang/remarks.$taal
#@ Bereken de Kans op Zwart of Rood
lijst=!shuffle 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,\
20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,\
40,41,42,43,44,45,46,47,48,49,50,51,52

cards=$empty
telwoorden=!record 59 of $remarkdir/commonremarks.$taal
helptext=!record 14 of lang/remarks.$taal
!if $R=1
    # 1-26=rood
    # 27-52=zwart
    kleuren=!record 16 of lang/remarks.$taal
    nummer=!randitem 2,3,4,5,6,7,8
    r=!randitem 1,2
    kleur=!item $r of $kleuren
    aantal=!randitem 1,$[27-$nummer]
    tot=$[$nummer+$aantal]
    t=0
    !for p=1 to $nummer
	!increase t
	!if $t=8
	    t=0
	    cards=!append line <br> to $cards
	!endif
	cards=!append line <img src="$module_dir/cards/0.gif"> to $cards
    !next p
    zz=0
    rr=0
    t=$nummer
    !for p=1 to $aantal
	num=!item $p of $lijst
	!if $num>26
	    !increase zz
	!else
	    !increase rr	
	!endif        
	index=!record $num of lang/index.$taal
        gif=!item 1 of $index
	!increase t
	!if $t>7
	    t=0
	    cards=!append line <br> to $cards
	!endif
        cards=!append line <img src="$module_dir/cards/$gif"> to $cards
    !next p    
    G=1
    !if $r=2
	!for p=1 to $nummer
	    G=$[$G*(27-$rr-$p)/(53-$aantal-$p)]
	!next p
    !else
	!for p=1 to $nummer
	    G=$[$G*(27-$zz-$p)/(53-$aantal-$p)]
	!next p
    !endif
    !if $r=1
	ding=$zz
    !else
	ding=$rr
    !endif		
    GG=$[(round($rounding*$G))/$rounding]
    answer$n=$G
    aa=!record 18 of lang/remarks.$taal
    textanswer$n=$aa
    #@ Er lagen $zz zwarte kaarten en $rr rooie kaarten omgedraaid op de tafel<br>\
    #@ De kans dat de $F kaarten ,die nog niet waren omgedraaid, allemaal $kleur zijn , is $(answer$n) (afgerond ongeveer $GG )<br>Deze kun je als volgt uitrekenen:<p>

    F=!item $nummer of $telwoorden
    ss=!record 17 of lang/remarks.$taal
    #@ Ik heb een goed geschud pakje eerlijke kaarten.<br>\
    #@ Ik pak $tot kaarten van het stapeltje en leg ze op tafel.<br>\
    #@ Ik draai er $aantal om. (Zie image)<br>\
    #@ Hoe groot is de kans dat de $F nog niet omgedraaide kaarten allemaal <em>$kleur</em> zijn ?<br>
    question$n=$ss<p>$cards

    texanswer$n=\frac{\left(\begin{array}{c}26-$ding\\$nummer\end{array}\right)}{\left(\begin{array}{c}52-$aantal\\$nummer\end{array}\right)}=\frac{\left(\begin{array}{c}$[26-$ding]\\$nummer\end{array}\right)}{\left(\begin{array}{c}$[52-$aantal]\\$nummer\end{array}\right)}\simeq $(answer$n) \simeq $GG   
 !exit
!endif

!if $R>1
    !if $R=2
	keuze=!randitem 0,1
	!if $keuze=0
	    r=!randitem 4,5,6,7,8,9,10
	    z=1
	    opkop=$[$r+1]
	!else
	    r=1
	    z=!randitem 4,5,6,7,8,9,10
	    opkop=$[$z+1]
	!endif
    !else	        
	opkop=!randitem 4,5,6,7,8,9,10,11,12,13,14
	r=!randint 1,$[$opkop-1]
	z=$[$opkop-$r]
    !endif
    aantal=!randint 1,$[27-$opkop]
    tot=$[$opkop+$aantal]
    t=0
    !for p=1 to $opkop
	# 1-26=rood
	# 27-52=zwart
	!if $t>7
	    t=0
	    cards=!append line <br> to $cards
	!endif	    
	!increase t
	cards=!append line <img src="$module_dir/cards/0.gif"> to $cards
    !next p
    zz=0
    rr=0
    t=$opkop
    !for p=1 to $aantal
	num=!item $p of $lijst
	!if $num>26
	    !increase zz
	!else
	    !increase rr	
	!endif        
	index=!record $num of lang/index.$taal
        gif=!item 1 of $index
	!if $t>7
	    t=0
	    cards=!append line <br> to $cards
	!endif
	!increase t
        cards=!append line <img src="$module_dir/cards/$gif"> to $cards
    !next p 
    t1=$[26-$zz]
    t2=$[26-$rr]
    t3=$[52-$aantal]
    T=$[factorial($t1)*factorial($t2)*factorial($opkop)*factorial($t3-$opkop)]
    N=$[factorial($z)*factorial($t1-$z)*factorial($r)*factorial($t2-$r)*factorial($t3)]
    answer$n=$[$T/$N]
    GG=$[(round($rounding*$(answer$n)))/$rounding]

    aa=!record 19 of lang/remarks.$taal
    textanswer$n=$aa
    #@ We hebben 26 zwarte kaarten in een spelletje.<br>Er liggen al $zz zwarte kaarten\
    #@ omgedraaid op tafel.<br>Dus we hebben nog 26-$zz=$t1 zwarte kaarten over.<br>\
    #@ We hebben 26-$rr = $t2 rooie kaarten over.<br>\
    #@ We hebben in het totaal 52-($rr+$zz) = $t3 niet-omgedraaide kaarten<br>Dus:<br>  
    F=!item $opkop of $telwoorden
    ss=!record 20 of lang/remarks.$taal
    question$n=$ss<p>$cards
    #@ Ik heb een goed geschud pakje eerlijke kaarten.<br>\
    #@ Ik pak $tot kaarten van het stapeltje en leg ze op tafel.<br>\
    #@ Ik draai er $aantal om. (Zie image)<br>\
    #@ Hoe groot is de kans dat er van de $F nog niet omgedraaide kaarten $r rood zijn en $z zwart ?

    texanswer$n=\frac{\left(\begin{array}{cc}$t1\\$z\\\end{array}\right)\cdot \left(\begin{array}{cc}$t2\\$r\\\end{array}\right)}{\left(\begin{array}{c}$t3\\$opkop\end{array}\right)} \simeq $(answer$n) \simeq $GG  

 !exit
!endif


