!if $taal=nl
    nivo_title=Tel de breuken op.
    somtekst1=Tel de volgende breuken bij elkaar op<br>\
    en vereenvoudig de uitkomst zo ver mogelijk:<br>
!else
    nivo_title=Addition on fractions
    somtekst1=Add the bext fractions,<br>and reduce the outcome
!endif
bewerking=bewerking1.proc
    
!if $negatief=0
    lijst_a=!shuffle 2,3,4,5,6,7
    lijst_b=!shuffle 4,5,6,7,8,9,10
    lijst_c=!shuffle 2,3,4,5,6,7
    lijst_d=!shuffle 7,8,9,10,11,12,13,14,15
!else
    lijst_a=!shuffle 2,3,4,5,6,-2,-3,-4,-5,-6
    lijst_b=!shuffle 4,5,6,7,8,9,10,-4,-5,-6,-7,-8,-9,-10
    lijst_c=!shuffle 2,3,4,-2,-3,-4
    lijst_d=!shuffle 7,8,9,10,11,12,13,15,-7,-8,-9,-10,-11,-12,-13,-15
!endif
    
totaal=$empty
R=$graad
!for n=1 to $aantal_sommen
    a=!item $n of $lijst_a
    c=!item $n of $lijst_c
    !if $graad=0
	R=$n
    !endif	
    !if $R=1
	b=!item $n of $lijst_b
	b=$[abs($b)]
	d=$b
	f=$b
	e=!randitem 1,2,3,4
    !endif
    !if $R=2
	b=$[(abs($a))+$n]
	d=$b
	e=!randitem 1,2,3,4
	f=$[2*$e]
    !endif
    !if $R=3
	b=$[$a+$n]
	d=$b
	f=!randitem 2,3,4,5,6    
	e=!randitem 1,2,3,4
    !endif	
    !if $R>3    
	d=!item $n of $lijst_d	
	e=$n
	b=!item $n of $lijst_b
	f=!item $[$n+1] of $lijst_d
    !endif
    som$n=($a)/($b) + ($c)/($d) + ($e)/($f) 
    opgave$n=\frac{$a}{$b} + \frac{$c}{$d} + \frac{$e}{$f}
    totaal=!append line $(som$n) to $totaal
    totaal=!append line printtex($(som$n)) to $totaal 
!next n

totaal=!exec pari $totaal

i=1
!for n=1 to $aantal_sommen
    GOED$n=!line $i of $totaal
    goed$n=!line $[$i+1] of $totaal
    i=$[$i+2]	 
!next n
