
cmake_minimum_required(VERSION 3.14)

list(APPEND
   CMAKE_MODULE_PATH
   ${CMAKE_CURRENT_SOURCE_DIR}/config/cmake
  )

include(utils)
ensure_out_of_source_build()

project(
  "libgridxc"
  LANGUAGES "Fortran"
  VERSION "2.0.2"
  DESCRIPTION "Library for XC computation on grids"
)

# Follow GNU conventions for installing directories
include(GNUInstallDirs)

# Avoid 'liblibgridxc' installed library names
set(LIBRARY_OUTPUT_NAME "gridxc")

# General configuration information
add_subdirectory("config")

# Compiler flags
include(flags)

option(WITH_MPI "Whether libgridxc should support MPI-parallelism" FALSE)
option(WITH_LIBXC "Whether libgridxc has a libxc interface" FALSE)
option(WITH_GRID_SP "Whether libgridxc has a single-precision (cellxc only) interface" FALSE)

if(WITH_MPI)
  if (NOT TARGET MPI::MPI_Fortran)
    find_package(MPI REQUIRED)
  endif()
endif()

# Collect source of the project
set(srcs)
add_subdirectory("src")

add_library(
  "${PROJECT_NAME}-lib"
  "${srcs}"
)

#-------------
#  This is a record of a feature that can be checked programmatically when
#  configuring clients if libgridxc is used as a pre-compiled library, but
#  not if the libgridxc source is compiled by the client.
#
set(LIBGRIDXC_HAS_PROCEDURE_POINTERS TRUE CACHE BOOL "libgridxc uses procedure pointers")
#-------------

set_target_properties(
  "${PROJECT_NAME}-lib"
  PROPERTIES
  POSITION_INDEPENDENT_CODE TRUE
  OUTPUT_NAME "${LIBRARY_OUTPUT_NAME}"
  VERSION "${PROJECT_VERSION}"
  SOVERSION "${PROJECT_VERSION_MAJOR}"
  Fortran_MODULE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/include"
)

if(WITH_LIBXC)

 if (NOT TARGET Libxc::xc_Fortran)
  find_package(CustomLibxc)
  if (TARGET Libxc::xc_Fortran)
    message(VERBOSE "Defining new target libxc::XC_Fortran...")
    add_library(libxc::XC_Fortran INTERFACE IMPORTED)
    target_link_libraries(libxc::XC_Fortran INTERFACE Libxc::xc_Fortran)
  endif()
 endif()

 if(NOT LIBXC_Fortran_FOUND)
   message(WARNING
    "Libxc support has been requested ${WITH_LIBXC} : ${LIBXC_Fortran_FOUND}, but the fortran libxc library cannot be\
 found.")
   message(FATAL_ERROR "Libxc could not be found by CMake")
 endif()

  target_compile_definitions(
  ${PROJECT_NAME}-lib
  PRIVATE
  HAVE_LIBXC
  )

  target_link_libraries(
    "${PROJECT_NAME}-lib"
    PUBLIC
    libxc::XC_Fortran
  )
endif()

if(WITH_GRID_SP)
  target_compile_definitions(
  ${PROJECT_NAME}-lib
  PUBLIC
  GRID_SP
  )
endif()


if(WITH_MPI)
  target_compile_definitions(
  "${PROJECT_NAME}-lib"
  PRIVATE HAVE_MPI
  )

  target_link_libraries("${PROJECT_NAME}-lib" PUBLIC MPI::MPI_Fortran)

endif()

target_include_directories(
  "${PROJECT_NAME}-lib"
  PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/include>
  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/${module-dir}>
)

# Export targets for other projects
add_library("${PROJECT_NAME}" INTERFACE)
target_link_libraries("${PROJECT_NAME}" INTERFACE "${PROJECT_NAME}-lib")
install(
  TARGETS
  "${PROJECT_NAME}"
  "${PROJECT_NAME}-lib"
  EXPORT
  "${PROJECT_NAME}-targets"
  LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
  ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
)
install(
  EXPORT
  "${PROJECT_NAME}-targets"
  NAMESPACE
  "${PROJECT_NAME}::"
  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}"
)
install(
  DIRECTORY
  "${CMAKE_CURRENT_BINARY_DIR}/include/"
  DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${module-dir}"
)
# Package license files
install(
  FILES
  "COPYING"
  DESTINATION "${CMAKE_INSTALL_DATADIR}/licenses/${PROJECT_NAME}"
)

add_subdirectory("docs")

# add the testsuite

enable_testing()
add_subdirectory("Testers")
