project(dconf-qt)
cmake_minimum_required(VERSION 2.6.0)

# Versions
## Package version
set(dconf_qt_VERSION_MAJOR 0)
set(dconf_qt_VERSION_MINOR 0)
set(dconf_qt_VERSION_PATCH 0)
set(dconf_qt_VERSION ${dconf_qt_VERSION_MAJOR}.${dconf_qt_VERSION_MINOR}.${dconf_qt_VERSION_PATCH})

## Lib version
### Bump this one when a binary-incompatible change is introduced
set(dconf_qt_lib_SOVERSION 0)

### Bump this one when the API is extended in a binary-compatible way
set(dconf_qt_lib_API_VERSION 0)

### Bump this one when changes do not extend the API
set(dconf_qt_lib_PATCH_VERSION 0)

set(dconf_qt_lib_VERSION ${dconf_qt_lib_SOVERSION}.${dconf_qt_lib_API_VERSION}.${dconf_qt_lib_PATCH_VERSION})

# dist targets
set(ARCHIVE_NAME libdconf-qt-${dconf_qt_VERSION})
add_custom_target(dist
    COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
        | bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
    )

add_custom_target(distcheck
    COMMAND cd ${CMAKE_BINARY_DIR}
    && rm -rf ${ARCHIVE_NAME}
    && tar xf ${ARCHIVE_NAME}.tar.bz2
    && mkdir ${ARCHIVE_NAME}/build
    && cd ${ARCHIVE_NAME}/build
    && cmake -DCMAKE_INSTALL_PREFIX=../install ..
    && make
    && make install
    )
add_dependencies(distcheck dist)

# Dependencies
include(FindPkgConfig)
find_package(Qt4 REQUIRED)
pkg_check_modules(GLIB REQUIRED glib-2.0)
pkg_check_modules(DBUS REQUIRED dbus-1)
pkg_check_modules(DCONF_DBUS REQUIRED dconf-dbus-1)

include_directories(
    ${QT_INCLUDE_DIR}
    ${QT_QTCORE_INCLUDE_DIR}
    ${QT_QTDBUS_INCLUDE_DIR}
    ${QT_QTDECLARATIVE_INCLUDE_DIR}
    ${QT_QTGUI_INCLUDE_DIR}
    ${GLIB_INCLUDE_DIRS}
    ${DBUS_INCLUDE_DIRS}
    ${DCONF_DBUS_INCLUDE_DIRS}
    ${CMAKE_SOURCE_DIR}/lib
    )

add_subdirectory(lib)
add_subdirectory(qml)
